Урок 11. Умножение и деление

Поход на рынок, как правило, заканчивается покупкой какого-либо товара. Если мы хотим купить несколько единиц товара одного наименования, то продавец посчитает нам итоговую сумму с использованием простейшего компьютера – микрокалькулятора. В аналогии с ассемблером при умножении товаров программа микрокалькулятора будет оперировать с числами без знака, поскольку нельзя купить минус три пури или минус пять круассанов. Чтобы есть и худеть, даже если очень бы хотелось

Умножение чисел без знака

Допустим, нам требуется сделать для нашего микрокалькулятора программу умножения количества товаров и цен. Применим команду ассемблера MUL для умножения беззнаковых чисел. Работать с этой командой просто, первый множитель по умолчанию хранится в регистре AL или AX, а второй множитель команде передаётся как единственный операнд – хранимый в регистре или в памяти.

Размер операнда	Множитель	Результат
Байт	AL	AX
Слово	AX	DX:AX

Как видно из таблицы, длина множителя (байт или слово) определяются по размеру переданного операнда. Если команда MUL перемножает два байтовых операнда, результатом будет слово, а если перемножаются двухбайтовые операнды, результатом будет двойное слово. При умножении в ассемблере разрядность результата будет ровно в 2 раза больше каждого из исходных значений. Говоря простым языком, если мы перемножаем числа одинаковой разрядности между собой, например 8 битное на 8 битное, то результат будет максимум из 16 бит.

mul bl    ;AX = AL * BL
mul ax    ;DX:AX = AX * AX

1 2	mul bl ;AX = AL * BL mul ax ;DX:AX = AX * AX

Если умножаются два операнда размеров в байт, то результат умножения помещается в регистр AX, а при умножении двух слов, результат комбинируется в регистрах DX:AX, где старшее слово результата будет в DX, а младшее в AX. Не всегда результатом умножения двух байт будет слово или при умножением двух слов – двойное слово. Если старшая часть результата содержит ноль, то флаги CF и OF будут также равны нулю. Соответственно старшую часть результата умножения можно игнорировать, что может быть полезно в определенных случаях.

Умножение чисел со знаком

Теперь переходим к миру математики, в котором знаковые числа перемножаются не реже беззнаковых. В ассемблере для таких операций есть команда IMUL. Инструкция имеет три формы, разнящиеся числом операндов:

Вызов с одним операндом – аналогично команде MUL. Передаваемым операндом может быть регистр или значение в памяти. Операнд умножается на значение в AL (операнд – байт) или AX (операнд – слово). Результат хранится в AX или комбинируется в DX:AX соответственно.

Вызов с двумя операндами – в этой форме перезаписываемый операнд назначения (первый множитель) умножается на передаваемый операнд — источник (второй множитель). В качестве перезаписываемого операнда должен указываться регистр общего назначения, а вторым операндом может быть непосредственное значение, регистр общего назначения или область памяти. Младшая часть результата помещается в перезаписываемый операнд, старшая часть (дважды от размера операнда – источника) отсекается.

Вызов с тремя операндами – в этой форме используется операнд назначения и два операнда -источника, содержащие первый и второй множители. Первый множитель, которым может быть регистр общего назначение или область памяти, умножается на второй множитель (непосредственное значение). Итоговое произведение операндов (дважды от размера первого операнда – источника) усекается и хранится в операнде назначения (регистр общего назначения).

Примеры использования команды IMUL:

imul bl                 ;AX = AL * BL
imul cx                 ;DX:AX = AX * CX
imul si,-13             ;SI = SI * -13
imul bx,si,123h         ;BX = SI * 123h

imul bl ;AX = AL * BL

imul cx ;DX:AX = AX * CX

imul si,-13 ;SI = SI * -13

imul bx,si,123h ;BX = SI * 123h

Для первой формы флаги CF = 0 и OF = 0 означают, что результат умножения поместился в младшей части, в то время как CF = OF = 1 для команды IMUL в форме с двумя или тремя операндами сигнализируют переполнение, то есть потерю старшей части результата.

Деление чисел без знака

Команда DIV используется для выполнения деления беззнаковых чисел с остатком. Если при умножении разрядность произведения всегда в два раза больше множителей, то при делении действует обратный принцип – большим разрядом является делимое, а частное всегда в два раза меньше делимого. Инструкция принимает единственный операнд – делитель, помещаемый в регистр общего назначения или в память. Размер делителя распределяет делимое, частное и остаток согласно таблице:

Размер операнда (делителя)	Делимое	Частное	Остаток
Байт	AX	AL	AH
Слово	DX:AX	AX	DX

Операция деления в ассемблере может вызывать прерывание (подробнее о прерываниях будет написано в одном из следующих уроков) в ряде случаев:

При делении на ноль;
Когда происходит переполнение частного, то есть результат не помещается в отведенную разрядность (например, если делимое – слово (1000), а делитель – байт (2), то результат (500) не поместится в байт).

Примеры:

div cl   ;AL = AX / CL, остаток в AH
div di   ;AX = DX:AX / DI, остаток в DX

1 2	div cl ;AL = AX / CL, остаток в AH div di ;AX = DX:AX / DI, остаток в DX

Деление чисел со знаком

Команда IDIV используется для деления чисел со знаком. Вызов аналогичен команде DIV – передаётся единственный аргумент – делитель, который неявно определяет размеры делимого, частного и остатка. Прерывание генерируется, если выполняется деление на ноль или частное превышает отведенную разрядность.

Программа к уроку

Применим полученные знания о командах деления и умножения для написания простой программы вычисления общего пройденного пути, имея исходные скорость, ускорение, время и расстояние:

s= s₀+ v₀t + at²/2

use16
org 100h

;===== Часть формулы: v0*t =====
mov al,[v]     ;AL = v0
mov bl,[t]     ;BL = t
mul bl         ;AX = AL * BL
mov si,ax      ;Произведение в SI

;===== Часть формулы: (a*t^2)/2 =====
mov al,[t]      ;AL = t
mul bl          ;AX = AL * BL = a*t
mov bl,[a]      ;BX = a
mov bh,0        ;BX - второй множитель, поэтому прибираемся в BH
mul bx          ;DX:AX = AX * BX = a*t^2
mov bx,2        ;BX = 2
div bx          ;DX:AX / BX = a*t^2 / 2

;===== Складываем все вместе =====
add ax,si        ;v0*t + (a*t^2)/2
add al,[s]       ;|
adc ah,0         ;|... + s0

mov [r],ax       ;Храним результат в [r]


mov ax,4C00h     ;|
int 21h          ;|Заверешение программы

;--------------------------------------
s db 180
v db 7
a db 4
t db 41
r dw ?

use16

org 100h

;===== Часть формулы: v0*t =====

mov al,[v] ;AL = v0

mov bl,[t] ;BL = t

mul bl ;AX = AL * BL

mov si,ax ;Произведение в SI

;===== Часть формулы: (a*t^2)/2 =====

mov al,[t] ;AL = t

mul bl ;AX = AL * BL = a*t

mov bl,[a] ;BX = a

mov bh,0 ;BX - второй множитель, поэтому прибираемся в BH

mul bx ;DX:AX = AX * BX = a*t^2

mov bx,2 ;BX = 2

div bx ;DX:AX / BX = a*t^2 / 2

;===== Складываем все вместе =====

add ax,si ;v0*t + (a*t^2)/2

add al,[s] ;|

adc ah,0 ;|... + s0

mov [r],ax ;Храним результат в [r]

mov ax,4C00h ;|

int 21h ;|Заверешение программы

;--------------------------------------

s db 180

v db 7

a db 4

t db 41

r dw ?

В 8-й строке результат умножения сохраняется в регистре SI. В 14-й строке старшая часть регистра BX – BH выставляется в ноль, что корректно только для беззнаковых чисел. Попытка присвоить ноль старшей части регистра, хранящего число со знаком может привести к ошибке, если младшая часть регистра хранит отрицательное число. Обратите внимание на строках 21-22 прибавление байта из переменной [s0] к слову AX происходит в два этапа: прибавление числа к AL, и корректировкой на перенос прибавлением нуля к AH.

Упражнение к уроку (1):

z = a² + 2ab + b²

Числа в формуле используйте 16 битные целые без знака.

Упражнение к уроку (2) (продвинутое):

Используя школьный курс сложения столбиком и команды MUL и ADD, напишите программу для умножения 32-битных чисел без знака. Результатом будет 64-битное число без знака.